法師巨集2.0 (作者:Edwin)

JDP

參考資料：
1.北美法師論壇Zarakaar的Mage Macro Guide for 2.X
[ http://forums.worldofwarcraft.com/thread.html?topicId=73339182&sid=1 ]
2．歐洲法師論壇Flight的Mage Macros 2.0
[ http://forums.wow-europe.com/thread.html?topicId=93909906&sid=1 ]
測試版本：2.08

一．前言
TBC從70級開始：競技場，風暴之眼，卡拉贊，英雄副本，25人raid…
當欣賞著灼燒老祖Otherguy鬼魅般的步伐（[ http://www.warcraftmovies.com/movieview.php?id=36161 ]）以及老冰法Faxmonkey的冰槍風箏時（[ http://www.warcraftmovies.com/movieview.php?id=32863 ]），我常常會問自己：你準備好了嗎？
所謂準備工作可以是多方面的，例如宏和插件，在今後的pvp戰鬥以及新一輪的副本farm中，適合版本2.0的宏可以幫你在操作上更上一層樓，因為，這些是可以實實在在提升的，意識反映與團隊配合往往要看個人的天分和努力程度。那麼先讓我們看看 2.0中，宏的使用有了什麼樣的變化。
二．宏2.0的變化
翻譯自：[ http://magewiki.wikispaces.com/Macros ]
1.語句 /script的諸多功能如施法，確定目標或者使用道具無法再被用於插件及宏中，現在他們受到保護並僅能用於安全模塊。
註：我們不能再在施法（CastSpellByName()）或使用物品（UseInventoryItem()）前先確定你是否在流鼻血或者冰箱是不是冷卻中。
2. 法術例如冰箱現在會產生一個1.5秒的公共施法時間，你可以通過點掉buff或者使用語句 /cancelaura Ice block來解決 （事實上，下文有個很棒的宏可以完全解決這個糟糕的改變）
3. 奧術智慧目前會根據對像等級自動調整施法等級（精明的暴雪一直在吸收優秀插件中的精華並在一個個補丁中整合進自己的系統——免費，多擇而且受人歡迎，真是不折不扣的奸商）
4. 如果宏的第一步失敗，那麼隨之的後續所有步驟都會失敗，即使在公共冷卻中，例如，你無法：
/cast Ice block
/cast Coldsnap
如果冰箱失敗（比如在冷卻），寒流將無法施放。
5. 你無法用宏來幫你自動售賣灰色垃圾（奸商插件可以完美解決這個問題）
6. 增加了#and和#show語句

三．法師宏
攻擊性宏：
1.飛彈宏
/cast [nochanneling:Arcane Missiles] Arcane Missiles
註：重複按鍵將不會取消你的飛彈釋放，隨著奧系天賦的開發這個宏將有著越來越多的上鏡幾率2.冰槍宏
/stopcasting
/cast Ice Lance
註：雖說冰槍第一原則就是別討論它，但我還是要說，冰槍在目前剛開的TBC是破壞平衡的存在，但由於魔傷加成係數低下及需要冰凍目標才能發揮威力這個先決條件，當後期裝備到達高端時應當能達到平衡。至於暴擊的次數，冰環的8秒可以釋放5次：
秒：0（冰環）1 2 3 4 5 6 7 8（解凍）
冰槍次數 1 2 3 4 5
五次全暴可以打掉某些70級精英怪一半的血量，連暴三四次是很經常的。水元素，霜刺及寒冰指環與之配合能重新詮釋冰法的爆發力。所以如果被冰法凍住，請第一時間使用你的技能或徽記解冰。
3.起手火球宏
/cast [nocombat] Pyroblast; Fireball
註：作為一個起手技或者拉怪用，你應當不在戰鬥狀態
4．氣定效果火球宏
/cast [modifier:alt] Pyroblast; Fireball
註：如果靈風套特效觸發（10秒內下個法術瞬放）或者有了類似的氣定效果，比如otherguy的流氓寶石：[ http://www.wowhead.com/?item=25893 ] 法術有2%幾率產生氣定效果，持續4秒，下個法術瞬放。可以用這個宏施放火球，或者按住alt鍵配合施放大火球。
5．冰箭風箏宏
/cast [modifier:alt] Frostbolt(rank 1); Frostbolt
註：按住alt鍵則是一級冰箭，否則是頂級冰箭。
6．反潛宏
按需使用
/cast [button:2] Arcane Explosion(Rank 1); Arcane Explosion
註：右鍵點擊施放一級奧暴，直接點擊為頂級
/cast [modifier:alt] Arcane Explosion(Rank 1); Arcane Explosion
註：按住alt配合為一級奧暴，否則是頂級
/cast [nocombat] Arcane Explosion(Rank 1); Arcane Explosion
註：如果不在戰鬥狀態施放一級，反之頂級
帶小號下副本必須，直接拉完副本所有怪一起a掉，或者野外殺低級分散怪，如Silisus的風元素.
7.暴雪烈焰風暴整合宏
/cast [modifier:alt] Flame Strike; Blizzard
註：按住alt是烈焰風暴，否則是暴雪。由於水元素的存在，法師AOE的戰術多樣化了：例如冰錐冰環閃爍雙暴雪，召喚水元素，冰錐冰環，讀秒烈焰風暴連冰錐，然後自身的冰環又好了。
8．序列攻擊宏
/castsequence reset=7 Arcane Blast, Scorch, Scorch, Scorch
註：出於魔法使用效率考慮，連按這個宏將施放三次灼燒，然後一個奧術衝擊([ http://www.wowhead.com/?spell=30451#z0z ])，如果7秒內沒使用它，將重置為奧術衝擊起始。奧術衝擊的加速施法效果將改變副本中單一的冰彈火球模式，今後和獵人一樣，一個合理的輸出模式將大大提高你的魔法效率和dps.對某些冰系免疫的怪，這個宏也很有用。
9．友善目標協助宏
/cast [harm]Fireball; [target=targettarget]Fireball
註：你可以用別的魔法替代這裡的火球術，這個宏將對你目標的目標施放魔法，如果你的目標是友善單位的話。
10．燃燒火球
/cast Combustion
/stopcasting
/cast Fireball
註：沒變化
11．加速攻擊宏
/use Mind Quickening Gem
/stopcasting
/cast Berserking
/stopcasting
/cast Fireball
註：隨著施法加速等級設定的加入，可以想像今後會有越來越多的相關裝備，法師們又要為一種新的屬性頭疼了。這個宏將使用思維加速寶石（[ http://www.wowhead.com/?item=19339 ]）並且施放巨魔的種族天賦再施法。
12．氣定大火球
/stopmacro [help]
/cast Presence of Mind
/stopcasting
/cast Pyroblast
或者Ap+氣定大火
/stopmacro [help]
/cast Presence of Mind
/stopcasting
/cast Arcane Power
/stopcasting
/cast Pyroblast
13．氣定AP護符宏
/cast Presence of Mind
/stopcasting
/cast Arcane Power
/stopcasting
/use Vengeance of the Illidari
/stopcasting
/cast Pyroblast
註：一個強力的起手技，Vengeance of the Illidari （[ http://www.wowhead.com/?item=28040 ]），來到外域後第一個需要搞到手的東西
或者
/stopmacro [help]
/cast Presence of Mind
/stopcasting
/cast Arcane Power
/stopcasting
/use 13
/stopcasting
/cast Pyroblast
你的護符應當在上面的護符槽（裝備欄13位）。關於雙開TBC中有些特例，比如有兩個近戰+AP的可以雙開，有許多護符可以同時使用，可以肯定，今後挖掘護符之間的搭配將成為一個很有趣的命題，別像我那樣早早賣掉之後追悔莫及。
下面的宏可以在跑動中使用但需要連按四次
/stopmacro [help]
/castsequence Presence of Mind, Arcane Power, 13, Pyroblast
防禦性宏：
1．閃爍宏
/stopcasting
/cast Blink
/script FlipCameraYaw(180);
閃爍並調整為背視角看看是哪個賊do it from behind
2．解詛咒宏
/cast [target=mouseover, help] Remove Lesser Curse; [target=player] Remove Lesser Curse
如果你的對象或者鼠標所指身上有詛咒，將去除它，否則去除自己身上的一種詛咒
3．禁魔宏
/stopcasting
/cast Counterspell
停止目前的施法並立即禁魔目標
4．變羊宏
1）組隊變羊
/script if UnitSex(」target」)==1 then g=」female 」 else g=」male 」 end;s=」Sheeping 「..g..UnitLevel(」target」)..」 %T」;c=」say」;if GetNumRaidMembers()>0 then c=」raid」 elseif GetNumPartyMembers()>0 then c=」party」 end;SendChatMessage(s,c)
/cast Polymorph
2）raid變羊
/cast detect magic
/focus
/script SetRaidTarget(」focus」, 1)
/script if UnitSex(」target」)==1 then g=」female 」 else g=」male 」 end;s=」I'm going to sheep a 「..g..UnitLevel(」target」)..」 %T」;c=」Party」;if GetNumRaidMembers()>0 then c=」raid」 end;SendChatMessage(s,c)
註：這兩個宏能告之你的隊友和隊伍你施法目標的性別，等級，如果你不在隊伍中，那僅僅施放變羊術，後面那個在施法前還放上了法術偵測，改良一下在pvp時對付薩滿有很好的效果。
3）智能變羊
/cast [button:2, target=focus] Polymorph; Polymorph
/focus [nobutton:2]
註：左鍵點擊將變羊你所集中的目標，例如副本裡需要控制一個遠程怪，右鍵將切回目標至你負責的怪並補羊。目前在2.08這幾個宏似乎有問題
4）隨機變羊
/castrandom Polymorph, Polymorphig, Polymorph:Turtle
註：什麼，你需要動物？找法師就對了。
5）下馬變羊
#showtooltip Polymorph
/dismount [mounted]
/cast Polymorph
註：以後就是下鳥了，法師還是空戰王者，請參考Faxmonkey錄像
5.冰箱宏
1) 公共CD終結者
/cancelaura Ice Block
/cast Ice Block
註：第一下冰箱，再按立即出棺
2）寒流冰箱
/cancelAura Ice Block
/castSequence reset=300 Ice Block, Cold Snap
註：連按可以做到雙冰箱。pvp的話進冰箱前請先召喚水元素出來，他能讓不少職業很鬱悶。如果你有浮冰天賦請將300改成240
3)解冰禁魔
/cancelaura Ice Block
/cast Counterspell
註：出了冰箱後立即禁魔
4）解冰閃爍
/cancelaura Ice Block
/cast Blink
註：pvp中如果你冰箱了而沒人加血，閃爍出去磕個瓶子也許是個好主意，pve中如果AOE明顯要失敗，比如有對方陣營干擾,這個宏也許可以救你一命。比較有意思的是我58時在地獄火半島AOE，從天而降一70法師，兩個冰箱後我雖然掛了，他也被數量眾多的小怪搞死。

6．一鍵守護
/cast [button:2] Frost Ward; Fire Ward
註：左鍵火守，右鍵冰守
7．神龜宏
/castSequence reset=30 Ice Barrier, Mana Shield
註：隨著資料片裡魔法護盾的強化，冰奧有了更多的本錢搞神龜流，這個宏會先後施放冰護和法盾，如果你有浮冰天賦請將30改成24。
8．繃帶宏
/use [help]Heavy Netherweave Bandage; [target=player]Heavy Netherweave Bandage
註：你也可以用暴雪整合了的自繃帶能力，布不是問題，尤其對法師而言，3.4k的效果卻很好，你也可以給水元素綁繃帶，當然這時候你的目標應該是隻羊。
其他宏：
1．協助宏
/cleartarget
/assist [player name]
清除現在的目標並選中你協助對象的目標，例如:
/cleartarget
/assist Edwina
在競技場裡你應當有數個類似的宏來配合你們組的dps職業
2．寶石宏
/castsequence [button:2] reset=120 Conjure Mana Emerald, Conjure Mana Ruby, Conjure Mana Citrine, Conjure Mana Jade, Conjure Mana Agate
/stopmacro [button:2]
/use Mana Emerald
/use Mana Ruby
/use Mana Citrine
/use Mana Jade
/use Mana Agate
註：右鍵將製造魔法寶石，左鍵則是按順序使用，冰錐流會用得到的。這個宏有時候會出現問題，表現為後面的寶石無法製造，期待達人改良。
3．喚醒宏
/castsequence [button:1] reset=10 Serpentcrest Life-Staff, Mar』li’s Touch, Evocation
/stopmacro [button:1]
/equip Time-Shifted Dagger
/equip The Saga of Terokk
/equip Nether-Core’s Control Rod
註：前兩次點擊將裝上你的高精神武器如Serpentcrest Life-Staff
（[ http://www.wowhead.com/?item=27791 ]）以及Mar』li’s Touch （[ http://www.wowhead.com/?item=19927 ]），第三次點擊開始喚醒.右鍵點擊將會切換會dps裝，他所列舉的裝備都是大眾裝備，你也可以配合itemrack插件搞一套精神裝專門用於提升喚醒的效率——法師現在被賦予了隱身.
4.智能廚師
/use [nomodifier] Conjured Glacial Water
/use [nomodifier] Conjured Croissant
/cast [modifier:shift, button:2] Conjure Food;[modifier:shift] Conjure Water
註：左鍵同時吃喝，shift+點擊造水，shift+右鍵造食，如果不到級別或者沒學會，請自行改動水食的名字。
5.智能魔法增/減幅
/cast [button:2, party] Amplify Magic; [button:2, target=player]Amplify Magic; [party] Dampen Magic; [target=player] Dampen Magic
註：左鍵魔法抑制，右鍵強化，如果目標為隊友，將buff他，否則buff自己。
6.自強化宏
/castsequence [target=player] reset=600 Dampen Magic, Arcane Intellect, Mage Armor
註：連按三次可以給自己加上你喜歡的buff,喜歡熔岩護甲的請自己替換，帶奶媽AOE的可以改成增幅。
7．強殖裝甲
/cast [modifier:alt]Ice Armor; [button:2]Molten Armor; Mage Armor
註：左鍵法師護甲，右鍵熔岩護甲，alt+點擊為冰甲
8．聯邦快遞
聯盟版：
/cast [modifier:shift] Portal: Exodar; [modifier:alt] Portal: Stormwind; [modifier:ctrl] Portal: Darnassus; Portal: Ironforge
部落版：
/cast [modifier:shift] Portal: Silvermoon; [modifier:alt] Portal: Undercity; [modifier:ctrl] Portal: Thunder Bluff; Portal: Orgrimmar
左鍵鐵爐（奧格），alt+左鍵暴風（幽暗）,ctrl+左鍵達拿（雷霆），shift+左鍵埃克索達（銀月）
如果需要去外域中立城請自行改動
或者/cast [button:2] Teleport:Shattrath; Portal:Shattrath
9．神遊四海
/cast [modifier:shift] Teleport: Exodar; [modifier:alt] Teleport: Stormwind; [modifier:ctrl] Teleport: Darnassus; Teleport: Ironforge
/cast [modifier:shift] Teleport: Silvermoon; [modifier:alt] Teleport: Undercity; [modifier:ctrl] Teleport: Thunder Bluff; Teleport: Orgrimmar
註：原理同上
寵物宏：
自認為也曾是個優秀的獵人，由於水元素的出現，大大加強了法師的可玩性和操作要求.獵人的假死和放寵吸引仇恨，現在法師都有了一定程度的相應能力，可以肯定，法師在副本裡能做到許多以前無法想像的事情。如何控制你自己和寶寶的走位與技能順序，讓對手在之間疲於奔命，不僅在pve,而且也在pvp方面給法師們帶來大量新要素。而目前我為了一個完美的鍵位設置快要抽瘋了，n多的技能+宏現在還要考慮寶寶…
1．放狗宏
/cast [nopet] Summon Water Elemental
/stopmacro [target=pettarget, exists]
/petattack
註：點擊一次將召喚水元素 （[ http://wow-europe.com/en/info/un ... ge/spells.html#none ]）
再點一次水元素將攻擊你的目標，在召喚後的lag時間內重複點擊可以讓寵物立即進入攻擊狀態並不會取消第一個水球
2．放狗冰環宏
/cast [nopet] Summon Water Elemental
/stopmacro [nopet]
/click PetActionButton5
註：如果你沒帶水元素，他將召喚一個，然後使用水元素的冰環，否則直接使用。
3．其他命令
/petattack 寵物攻擊
/petfollow 跟隨
/petstay 停留
/petpassive 被動模式
/petdefensive 防禦模式
/petaggressive 主動攻擊
/petautocaston 自動施放技能打開，比如冰球
/petautocastoff 自動施放技能關閉
重置宏:
/invite edwina
/script LeaveParty()
是的,它也回來了,伴隨我從44級祖爾法拉克直到55級離開瑪拉頓進入外域的新天地
四．題外話
資料片的法師也許不是空前的強大，但絕對可以說是最有可玩性的：水元素，隱身和冰槍這些新技能給法師帶來了全新的感覺；新天賦，新的法傷加成係數以及目前較為平衡的法系裝備設計則使我熱血沸騰，更何況對新副本的探索與資料片帶來的商機完全撫慰了我被盜的傷痛，66級開始AOE黑暗沼澤，67級開始solo 暗影圖書館，能做的事情真的很多很多.

Reference: http://cn.worldofming.com/?p=131

JDP

http://wow-en.curse-gaming.com/wiki/mage-macro-guide/