|
WoW 2.0巨集指南
常用指令
/cast
說明: 也可以用 /施放 後面接法術名稱
範例: /cast 火球術
/use
說明: 使用物品,飾品
範例: /use 靈巧碼表
/target
說明: 定義目標
範例: /施放 [target=pet, dead] 復活寵物
/focus
說明: 鎖定監控目標
範例:
/stopmacro
說明: 強制停止巨集
範例:
/castrandom
說明: 隨機施放法術
範例:
/userandom
說明: 隨機使用物品
範例:
/castsequence
說明: 按順序施放一組事先設定好的法術
範例:
設定巨集圖示時,如果選擇第一個?圖案
可在巨集中加入 # showtooltip 法術名稱,會自動對應該法術的圖示
巨集指令後可加上條件判斷, 條件成立即被執行
但只有一個動作可以被完成, 動作一旦觸發, 巨集即中止
語法: /施放 [條件一] 法術名稱;[條件二] 法術名稱; [條件三] 法術名稱;
條件判斷指令
[help] - 檢測目標是否為友善
[harm] - 檢測目標是否為敵對
[combat] - 檢測玩家本身是否在戰鬥中
[stance] 或 [stance:#] - 檢測你是否在姿態中
[stealth] - 檢測玩家本身是否潛行
[modifier] 或 [modifier:shift|ctrl|alt] - 檢測是否某個的鍵被按下
[equipped] - 檢測某個物品是否被裝備
[target] - 把當前目標改變為任何有效的單位
[actionbar] - 檢測目前動作條
[mounted] - 檢測是否騎馬
[swimming] - 檢測是否游泳
[flying] - 檢測是否飛行
[indoors] - 檢測是否在室內
[outdoors] - 檢測是否在室外
[button] - 檢測按鈕,預設為1(滑鼠左鍵)
[exists] - 檢測目標是否死亡
[dead] - 檢測目標是否存在
[pet] - 檢測否有召喚寵物
你可以在任何條件選項前加上 no 來得到反效果
如 nocombat 為非戰鬥的情況
用逗號 , 來分隔條件選項作用和 and 一樣,當條件選項同時成立時執行
用斜線 / 來分隔條件選項作用和 or 一樣,當其中一個條件選項成立時執行
<範例>
/施放 [help] 強效治療術
說明:
檢測目標是否為友善,當目標為友善時施放強效治療術。
/施放 [help] 強效治療術; 懲擊
說明:
第一組條件選項不成立時,則施放懲擊
/施放 [help, combat] 快速治療; [help, nocombat] 強效治療術; 懲擊
說明:
在你本身處於戰鬥中時為友方目標施放快速治療
如果你在非戰鬥中且目標為友方目標,則施放強效治療術
如果前兩項條件都不成立,則施放懲擊
/施放 [help] 強效治療術; [harm, combat] 懲擊; [harm, nocombat] 精神鞭笞
說明:
若目標為友方則施放強效治療術
若目標為敵方且是戰鬥中則施放懲擊
若目標為敵方但是非戰鬥中則對敵對目標施放精神鞭笞
/施放 [stealth] 伏擊; 背刺
說明:
玩家本身處於潛行時施放伏擊,否則就背刺
/施放 [nostealth] 背刺; 伏擊
說明:
玩家本身處於非潛行時施放背刺,否則就伏擊。
/施放 [actionbar:1] 強效治療術; [actionbar:2] 懲擊
說明:
當前動作條為第一組時施放強效治療術
如果是第二組則施放懲擊
如果為其他動作條則不做任何事情
/施放 [harm] 變形術
/stopmacro [noharm]
/p 正在把%t變羊!別去碰它!
說明:
目標為敵對目標時施放變形術
若目標不是敵對,則停止巨集動作
這時巨集並不執行下一行,故沒有訊息
當目標被變羊後則發出訊息
/施放 [pet] 召喚寵物; 復活寵物
說明:
在你沒有帶著寵物時召喚一個出來
否則的話則復活你的寵物
/施放 [pet wl] 俯衝; [pet:cat] 衝鋒; [pet] 低吼
說明:
在你帶著梟類寵物的時候施放俯衝
帶著貓類寵物時施放衝鋒
如果是其他寵物則施放低吼
/施放 [pet:虛空行者] 犧牲; [pet:魅魔] 誘惑
說明:
帶著虛空行者則施放犧牲
帶著魅魔則施放誘惑
/使用 [nomounted, outdoors] 黑色戰駒韁繩
說明:
在室外且沒有騎著坐騎時召喚坐騎
/dismount [mounted]
/userandom 紫色骷髏戰馬,霜狼嗥叫者的號角,迅捷祖利安猛虎,紅色骷髏戰馬,黑色戰狼,黑色作戰科多獸,黑色戰鬥迅猛龍
說明:
隨機挑選一隻坐騎
/施放 [target=pet, dead] 復活寵物; [nopet] 召喚寵物; 治療寵物
說明:
若你的寵物死亡了則復活它
如果沒有寵物則召喚寵物
否則就治療你的寵物
姿態條件範例:
當沒有標示姿態編號時,則玩家處於任一姿態都成立
聖騎士的光環在巨集條件選項系統中將不再被作為姿態處理
每個職業的特定姿態都有不同的編號,如下表:
戰士:1. 戰鬥 2. 防禦 3. 狂暴
牧師:1. 暗影形態
德魯伊:1. 熊 2. 水棲 3. 貓 4. 旅行 5. 梟獸/樹
盜賊:1. 潛行
/施放 [nostance] 熊形態
說明:
如果沒有在一個形態下,則變形到熊形態
/施放 [stance:1] 壓制; [stance:2] 破甲; [stance:3] 旋風斬
說明:
在戰鬥姿態下施放壓制
防禦姿態下施放破甲
狂暴姿態下施放旋風斬
/施放 [stance:1] 低吼; [stance:3] 爪擊
說明:
在熊形態施放低吼
在貓形態施放爪擊
/施放 [nostance:3] 獵豹形態
說明:
如果不在獵豹形態,則變形獵豹
裝備條件範例:
物品槽列表:
Two-Hand 雙手
Bag 包
Shirt 襯衫
Chest 胸部
Back 背部
Feet 腳
Finger 手指
Hands 手
Head 頭部
Held In Off-hand 副手物品
Legs 腿部
Neck 頸部
Ranged 遠程
Off Hand 副手
Shoulder 肩部
Tabard 徽章
Thrown 投擲
Trinket 飾品
Waist 腰部
One-Hand 單手
Main Hand 主手
Wrist 手腕
/施放 [equipped:雙手劍] 致死打擊; 英勇打擊
說明:
當你裝備著雙手劍時施放致死打擊
否則施放英勇打擊
/施放 [equipped:雙手劍/雙手錘/雙手斧/長柄武器] 致死打擊
說明:
在你裝備以上類型武器時施放致死打擊
/施放 [equipped:盾牌] 盾牌猛擊
說明:
在你裝備了盾牌的時候施放盾牌猛擊
/施放 [equipped:盾牌, equipped:匕首] 盾牌猛擊
說明:
僅在你同時裝備了盾牌和匕首時才施放盾牌猛擊
/施放 [noequipped:盾牌, equipped:副手] 暴怒
說明:
在你沒有裝備盾牌且副手裝備了武器的情況下施放暴怒
也就是說,在你雙手同時持有武器的時候條件才成立
/equip [nobutton:2,noequipped:Fishing Pole] 釣魚竿
/cast [nobutton:2,equipped:Fishing Pole] 釣魚
/equipslot [button:2] 16 主手裝備
/equipslot [button:2] 17 副手裝備
說明:
使用釣魚,若尚未裝備釣魚竿則裝備釣魚竿
如果以右鍵點擊,則是裝備回指定的武器
按鈕條件範例:
滑鼠按鍵編號:
1 = 滑鼠左鍵 (預設值)
2 = 滑鼠右鍵
3 = 滑鼠中鍵
4 = 滑鼠4號鍵
5 = 滑鼠5號鍵
/施放 [button:2, target=player] 快速治療; [help] 快速治療
說明:
於巨集按右鍵時向自己施放快速治療
於巨集按左鍵時向友方目標施放快速治療
[target=unit]
說明:
改變施法的目標,unit類型如下:
player = 玩家本身
target = 目標
targettarget =目標的目標
party1 = 隊員#1 即 F2
party2 = 隊員#2 即 F3
party3 = 隊員#3 即 F4
party4 = 隊員#4 即 F5
party1target =隊員#1的目標
party2target =隊員#2的目標
party3target =隊員#3的目標
party4target =隊員#4的目標
target的預設值就是當前所選定的目標
/施放 [help] 強效治療術
/施放 [target=target, help] 強效治療術
說明:
上述兩個巨集的功能相同
/施放 [target=player] 快速治療
說明:
向自己施放快速治療,並且不會改變你的目標
/施放 [help] 快速治療; [target=targettarget] 快速治療
說明:
如果目標是友善的,則向他施放快速治療
否則向目標的目標施放快速治療
/施放 [help, combat] 快速治療; [help, nocombat] 強效治療術; [target=targettarget, help, combat] 快速治療; [target=player] 強效治療術
說明:
如果你處於戰鬥中且目標友善時施放快速治療
如果你目標友善且沒有在戰鬥中則施放強效治療術
如果你處於戰鬥中且你目標的目標為友善,則向他施放快速治療
如果前面的條件都不成立,則向自己施放強效治療術
/施放 [target=none] 驅散魔法
說明:
等待你點選一個目標後施放驅散魔法
/use [target=player] 厚虛空布繃帶
說明:
無論當前目標是什麼,只會對自己使用厚虛空布繃帶
新的巨集命令
/castsequence [<條件選項>] reset=<#>/target/combat <法術1>, <法術2>, <法術3>
允許你在連續點擊某個巨集時,將其中定義的一系列法術逐個施放
當你第一次點擊這個巨集時,它施放列表中的第一個法術
第二次點擊的時候,施放第二個法術,以此類推
當它施放完最後一個時,又回到起始點開始迴圈
/castsequence 冰霜新星, 閃現
說明:
第一次按這個巨集,施放冰霜新星,再按一次,閃現
如果法術無法施放譬如冷卻,超出距離,法力不足等情況下
迴圈即中止,下一次再點這個巨集,它會從施放冰霜新星開始
/castsequence reset=24 冰霜新星, 閃現
說明:
加上 reset參數, 設定停用巨集之後,迴圈的重置時間
冰霜新星一般的冷卻時間為24秒
因此當你第一次點擊巨集時,它會施放冰霜新星
24秒內不再點選,它會重置到冰霜新星的狀態
/castsequence reset=combat/target 腐蝕, 獻祭, 痛苦詛咒
說明:
每當你改變目標,譬如目標死了,或選了新目標
迴圈即重置,下一次點選就會從新開始
/castsequence [nocombat] 尋找藥草, 尋找礦石
切換藥草、礦石雙採集
巨集範例
/施放 [stance:1] ; [stance:2] ; [stance:3]
說明:
一般姿態巨集
/施放 [stance:1] 壓制; 戰鬥姿態
說明:
一個很簡單的壓制巨集
/施放 [nocombat] 炎爆術; 火球術
說明:
如果沒有處於戰鬥則施放炎爆術
否則就施放火球術
/施放 [target=focus] 變形術
說明:
鎖定目標變羊
/focus [target=focus,noexists] target; [target=focus,dead] target
/castrandom [target=focus,harm] 變形術, 變豬術, 變龜術
/stopmacro [noharm]
/s %t 吃草中...
說明:
若【監視目標】不存在或已經死亡
則將【目前目標】設定成為【監視目標】
並對【監視目標】使用變豬術
/cast [button:2] 寒冰箭(等級 1);寒冰箭
說明:
左鍵:寒冰箭
右鍵:寒冰箭(等級 1)
/cast [button:2] 防護火焰結界;防護冰霜結界
說明:
左鍵:防護冰霜結界
右鍵:防護火焰結界
/use [harm] 13
/stopcasting
/use [harm] 14
/stopcasting
/cast [harm] 寒冰箭
說明:
當雙飾品沒在 CD 中就使用,並發射寒冰箭
/use [nomodifier] 魔法晶水
/use [nomodifier] 魔法肉桂麵包
/cast [modifier:shift,button:2] 造食術; [modifier:shift] 造水術
說明:
左鍵點擊同時啃麵包並喝水
Shift+左鍵則造水
Shift+右鍵則造食
/stopcasting
/cancelaura 寒冰屏障
/cast 閃現術
說明:
中斷目前施法、並解除冰箱
再使用閃現術
/stopcasting
/cancelaura 寒冰屏障
/cast [harm] 法術反制
說明:
中斷目前施法、並解除冰箱
若對方是敵對則使用法術反制
/focus target
/stopcasting
/cast [target=mouseover, help] 解除次級詛咒; [target=player] 解除次級詛咒
說明:
將【目前目標】設定成為【監視目標】
滑鼠所指的人物上若是友善且身上有詛咒,則解咒
否則解除自己身上的一種詛咒
/castSequence reset=30 寒冰護體,法力護盾
說明:
會先後施放【寒冰護體】
再點一次則施放【法力護盾】
/castsequence [target=player] reset=60 冰甲術,祕法智慧,寒冰護體
說明:
每60秒重置,連按三次
每次依序給自己施放喜歡的增益法術
/cast [button:2] 冰甲術; [modifier:alt] 熔火護甲; 魔甲術
說明:
右鍵施放冰甲術
Alt + 左鍵施放熔火護甲
左鍵施放魔甲術
/cast [modifier:shift] 傳送:銀月城; [modifier:alt] 傳送:幽暗城; [modifier:ctrl] 傳送:雷霆崖; 傳送:奧格瑪
說明:
Shift+左鍵施放銀月城傳送
Alt+左鍵施放幽暗城傳送
Ctrl+左鍵施放雷霆崖傳送
左鍵施放奧格瑪傳送
/cast [modifier:shift] 傳送門:銀月城; [modifier:alt] 傳送門:幽暗城; [modifier:ctrl] 傳送門:雷霆崖; 傳送門:奧格瑪
說明:
Shift+左鍵施放銀月城傳送門
Alt+左鍵施放幽暗城傳送門
Ctrl+左鍵施放雷霆崖傳送門
左鍵施放奧格瑪傳送門
/cast [nopet] 召喚水元素
/stopmacro [target=pettarget, exists]
/petautocaston
/petattack
說明:
點擊一次召喚水元素
再點一次水元素將攻擊你的目標
/cast [nopet] 召喚水元素
/stopmacro [nopet]
/click PetActionButton5
說明:
如果沒有水元素則召喚
如果已經有水元素則施放寵物攻擊技能
/施放 [target=targettarget, help] 強效治療術; [help] 強效治療術
說明:
若當前目標的目標為友善則施放強效治療術
否則向當前目標施放強效治療術
/施放 [combat] 治療寵物; [nocombat] 餵養寵物
/使用 [nocombat] <食物>
說明:
根據是否在戰鬥中餵養或治療寵物
# showtooltip 極效靈魂石
/cast [modifier:shift] 製造靈魂石
/stopmacro [modifier:shift]
/use [nomodifier] 極效靈魂石
/P [%T]已經被綁定
說明:
點選巨集使用靈魂石綁目標並發訊息
Shift + 點選巨集 製造靈魂石但不會發訊息
# showtooltip 極效治療石
/use [nomodifier] 極效治療石
/cast [modifier:shift] 製造治療石
說明:
點選巨集使用治療石
Shift + 點選巨集 製造治療石
/cast [nomodifier,button:2] 魔息術; [nomodifier,button:1] 偵測次級隱形
/cast [modifier:shift] 感知惡魔
說明:
滑鼠左鍵"偵測次級隱形",右鍵"魔息術"
Shift + 點選巨集"感知惡魔"
# showtooltip 召喚小鬼
/cast [button:2] 召喚地獄獵犬; [button:1] 召喚小鬼
說明:
左鍵召小鬼,右鍵召地獄犬
WoW 2.1新增巨集
* New conditional [flyable] which is true if you're in a location where you could use a flying mount
多了一個[flyable]的判斷選項,可以辨別是否可以使用飛行坐騎。
* You can use %f in chat text to refer to your focus, the same way %t or %n refers to your target.
如同%t代表目標的名字,%f現在可以代表Focus(監視目標)的名字。
* Added macro option support for /dismount
/dismount 指令可以使用判斷選項了。
* Macros containing conditionals will automatically update their visual feedback as appropriate during play.
加入條件判斷的巨集,會在執行過程中正確的對應到他們的圖示與狀態。
* #show and #showtooltip can be given conditionals and will update dynamically
#show 與 #showtooltip可以依照條件動態的更新圖示。
* #show and #showtooltip can be given a slot number, to display the appropriate feedback for that slot
#show 與 #showtooltip可以指定某個裝備部位(例:主手,胸部,飾品)的編號,並且顯示對應的狀態(例:cooldown)。
* Added bag and slot number support to: /castsequence, /cast, /castrandom, /use, /userandom, /equip, /equipslot
現在/castsequence, /cast, /castrandom, /use, /userandom, /equip, /equipslot
都可以使用背包編號或裝備部位編號來直接使用了。(所以現在可以直接使用某格裝備的戒指或飾品,當更換飾品或戒指後不需要改寫巨集。)
* New slash command /cancelform
新增一個指令/cancelform(取消姿態)
* The /equip command can take item identifiers specified as item:<id>: e.g. /equip [modifier:alt] item:25640
/equip(裝備)指令可以把物品編號當成物品來用了。
* You can provide several conditional clauses for a single action, which will be performed if any of the clauses evaluates to true. e.g. /cast [target=target,help,nodead] [target=targettarget,help,nodead] [target=player] Flash of Light
現在可以用多個條件對應一個動作了。(以前一個條件只能對應一個動作)
飛行座騎判斷
/use [outdoors,nocombat,noflyable] (座騎名稱)
/use [outdoors,nocombat,flyable] (飛行座騎名稱)
如果是術士或聖騎士的話
把第一行改成
/cast [outdoors,nocombat,noflyable] (召喚座騎名稱)
Reference: http://www.myorc.com/thread296558.html |
|